一些巨集 - WOW

分享一些巨集的寫法 (沒巨集不會玩..XD)
只寫自己熟的法/聖 其他有些常見的巨集就不分享了
分行的部分再接成一行 /或#才會是開頭
沒分行的巨集用網頁版可以直接複製貼上~


常用的幾個指令:
[@player] 對自己; [@focus] 對專注目標; [@mouseover] 對滑鼠目標
[@targettarget] 對目標的目標 (不太喜歡 因為目標不穩定)
[talent:a/b] 點了第a層第b個天賦會作用 (例: [talent:6/1])
[spec:1][spec:2] 在第1/2個專精下作用
[mod:xxx] 只有在按下後面寫的按鍵時才會作用 (例: [mod:shift] 按下shift作用)
[nogroup] 沒有組隊
[harm] 敵對目標; [help] 友方目標; [exists] 目標存在
※條件式判斷目標都是對指令內的目標
例: [@focus, harm] 是看專注目標是不是敵對, 不是當前目標

--
橘戒+大招
#showtooltip
/cast xxx <-填入使用的技能
/use [mod:shift][nogroup] 12

在團隊內 除非按下shift 不然不會開戒指
拜託沒事大招綁戒指的都加個nogroup阿~~
常用的slot id: 11/12 戒指12; 13/14 飾品1/2; 15 披風; 6 腰帶


自動切天賦(以法師第一層當例子)
#showtooltip
/cast [talent:1/1] 漸隱; [talent:1/2] 熾烈迅捷; [talent:1/3] 浮冰

看天賦自動切換的語法 換天賦就不用拉按鍵了

補註一下, 某些層天賦有專屬的技能名稱
這個狀況只會出現在這層天賦"所有技能都是主動技"+"不會取代現有技能"的情況
例如上面法師的第一層天賦不會適用 因為漸隱會取代冰箱

適用的例子 像是聖騎的第六層天賦(神聖稜石/聖光之錘/死刑宣判)
這層有個統一的名字叫"聖光武器"
利用/cast 聖光武器 可以一次表示這三個技能 同樣做到切天賦的效果
至於這名字怎麼找..點了天賦以後拖到技能欄 再點掉天賦 看技能看得到

--
法師 (主冰副奧)


第二層天賦
#showtooltip
/cast [talent:2/1, nobtn:2] 時光倒轉; [talent:2/3] 寒冰護體
/cancelaura 時光倒轉

用滑鼠右鍵點這個巨集會直接取消倒轉buff
可以把nobtn:2改成nomod:xxx 變成按特定按鈕時取消buff


第二層天賦 增強版
#showtooltip
/stopcasting [nobtn:2]
/run local h=math.floor(100*UnitHealth("player")/UnitHealthMax("player")) if
GetSpellCooldown(108978)==0 then print("時光倒轉前血量: "..h.."%") end
/cast [talent:2/1, nobtn:2] 時光倒轉; [talent:2/3] 寒冰護體
/cancelaura 時光倒轉

多加一行紀錄倒轉前血量 判斷要不要轉回去


第五層天賦
#showtooltip
/stopmacro [noharm]
/cast [talent:5/1, spec:1]冰霜炸彈; [talent:5/1, spec:2] 虛空暴雨;
[talent:5/3, spec:1] 寒冰新星; [talent:5/3, spec:2] 超級新星

避免新星對友方目標空放 浪費dps


第七層天賦
#showtooltip
/focus [talent:7/2]
/cast [talent:7/2] 稜彩水晶; [talent:7/3, spec:2] 秘法光球; [talent:7/3,
spec:1] 彗星風暴

連帶自動切換一起寫進去 點水晶時會先focus當前目標


奧衝/飛彈
#showtooltip 秘法衝擊
/cast [harm, exists, nochanneling:秘法飛彈] 秘法衝擊
/stopmacro [harm, exists]
/target [@focus]
/cast [nochanneling:秘法飛彈] 秘法衝擊


#showtooltip 秘法飛彈
/cast [@focus, mod:shift, nochanneling:秘法衝擊][harm, exists, nochanneling:
秘法衝擊] 秘法飛彈
/stopmacro [harm, exists][mod:shift]
/target [@focus]
/cast [nochanneling:秘法衝擊] 秘法飛彈

沒有目標或目標為友方時會對專注目標施法
配合上面水晶巨集 可以避免水晶消失時目標丟失的問題
另外為了配合恐懼預言 在預言觸發在目標身上時 按shift打飛彈會對專注目標施放


--
聖騎

補聖打無私審判
#showtooltip
/cast [@mouseover,harm,nodead][harm,nodead] 審判
/stopmacro [harm, nodead]
/targetenemy
/cast 審判
/targetlasttarget [harm]

優先對滑鼠目標施法; 目標為敵方施法; 目標為友方時自動找敵方施法
最後一行是為了在找不到敵方時目標不會亂轉
改個法術名稱就可以拿去別的職業用了~


第六層天賦
#showtooltip
/cast [@mouseover,harm,nodead,talent:6/1][harm,nodead,talent:6/1]
神聖稜石;[talent:6/2]聖光之錘;[@player,mod:shift,talent:6/3]
[talent:6/3,exists]死刑宣判
/stopmacro [harm,nodead][notalent:6/1]
/targetenemy
/cast 聖光武器
/targetlasttarget [harm,nodead]

第六層天賦整個寫進去 稜鏡部分用上個巨集的邏輯寫 差點爆字數
死刑宣判有按shift會先丟在自己頭上


第七層天賦
#showtooltip
/stopmacro [noexists, spec:2][harm ,spec:2][dead ,spec:2]
/cast [talent:7/1,spec:2] 虔信信標; [talent:7/1,spec:1,stance:2] 真理聖印
;[talent:7/1,spec:1] 正義聖印;[talent:7/2, spec:1] 六翼天使; [talent:7/2,
spec:2] 洞察信標

懲戒(專精1)/神聖(專精2)
前面寫一串是不想亂丟信標
懲戒點聖印舞的話 按這個巨集會在真理和正義中間切換


保護/犧牲
#showtooltip
/stopmacro [noexists][harm][dead]
/cast 保護聖禦
/stopmacro [nogroup]
/s 保護聖禦: %t


#showtooltip
/stopmacro [noexists][harm][dead]
/cast 犧牲聖禦
/stopmacro [nogroup]
/s 犧牲聖禦: %t

只對友方放招 團隊內有成功放到會喊話 不小心目標先掛了也不會丟到自己身上
btw, [@player]是指定法術目標為自己 不能做為判斷式
因此/stopmacro [@player]是沒有意義的 做不出"目標為自己時停止"的指令
如果有辦法做出這個指令的人請賜教 謝謝!


聖療
#showtooltip
/cast [@player, mod:shift] 聖療術
/stopmacro [noexists][harm][dead]
/cast 聖療術

按shift給自己聖療 其他跟上面保護/犧牲同理 我也不知道為什麼這個不做喊話


懲戒 十字軍聖擊
#showtooltip
/clearfocus [mod:shift]
/focus [mod:shift, harm, nodead]
/cast [@focus, nodead, exists][] 十字軍聖擊

配合轉火會掉dps的職業飾品用
按下shift會設定專注目標 之後施法都會優先打專注目標


--
補一個
坦僧的雕像巨集
#showtooltip
/click TotemFrameTotem1 RightButton
/cast 召喚玄牛雕像

按下去取消雕像 避免ADD


--
其他奇奇怪怪的東西

額外按鍵
/click ExtraActionButton1


一鍵分解
#showtooltip 分解
/run local f=DeM or CreateFrame("Button","DeM",nil,
"SecureActionButtonTemplate") f:SetAttribute("type","click")
f:SetAttribute("clickbutton",GetMouseFocus())
/cast 分解
/click DeM

附魔用 分解滑鼠指向的物品
可以改一下技能 拿去銘文磨草/珠寶分解舊礦等等


交換背包 須開啟銀行
/run for i = 1,4 do PickupBagFromSlot(19+i) PutItemInBag(67+i) end

把身上的所有背包跟銀行前1~4個包交換
如果把後面的67+i改成70+i則會變成後四個包
背包編號: 20~23 身上; 68~74 銀行


自動接受任務
/script T,F=T or 0,F or CreateFrame("frame")if X then print("自動接受
任務『關』")X=nil else print("自動接受任務『開』")X=function()local t=
GetTime()if t-T>1 then QuestFrameAcceptButton:Click()T=t end end end
F:SetScript("OnUpdate",X)

自動接收所有任務(包括npc和分享)


放棄所有任務
/run for i=1,GetNumQuestLogEntries() do SelectQuestLogEntry(i);
SetAbandonQuest(); AbandonQuest(); end


放銀行 須開啟銀行
/run for bag=0,4 do for slot=1,GetContainerNumSlots(bag) do local
item=GetContainerItemLink(bag,slot) if item and item:find("") then
UseContainerItem(bag,slot) end end end

把全部背包的東西丟進銀行 謹慎使用
填入item:find("")裡面的名稱 則可以搜尋特定物品放入(ex. item:find("護甲"))


自動寄信 須開啟信箱
/click MailFrameTab2
/run for b=0,4 do for s=0,32 do
l=GetContainerItemLink(b,s) if l and l:find("") then UseContainerItem(b,s)
end end end
/script if (GetSendMailItem())~=nil then SendMail("名稱-伺服器","Automail")end
/click MailFrameTab1

把全部背包的東西按順序寄給收件人(名稱-伺服器 自行修改)
多加了一行判斷式 讓沒有附件的情況下不會寄空信
同上 填入l:find("")裡面的名稱 可以只寄特定物品


Armory
/run local n=(UnitName("target")) r=string.sub(GetUnitName("target",true),
string.len(n)+2) if r=="" then r=GetRealmName() end
m="http://tw.battle.net/wow/zh/character/" .. r .. "/" .. n .. "/advanced"
SendChatMessage(m,"WHISPER",nil,UnitName("player"))

全部接成一行 勉強擠進字數限制了XD
看對方Armory用的 是有沒有這麼懶


計算怪數 做一些成就會用到(吧
/run local t,c,p=(UnitName("target")),0 for i=1,10000 do p=_G["NamePlate"..i]
if p and p:IsVisible() then c=c+(select(2,p:GetChildren()):GetRegions():
GetText()==t and 1 or 0) end end SendChatMessage((t.." : "..c),"SAY")

追蹤當前目標在場上的數量 要開血條



補一個最近學到的小知識 怎麼在巨集內po物品連結
1. 把物品貼到對話框 任意頻道
2. 做一個巨集 把要貼物品連結的位置留空
3. 按一下esc把遊標清掉
4. 按Enter打入/script MacroFrameText:Insert("")
5. 把遊標點到""中間 shift+按頻道 要貼的物品
6. Enter輸出
這樣就貼到巨集內囉


大概就這些~


--